archetype (adl_version=1.4)
	openEHR-EHR-EVALUATION.excluded.v1

concept
	[at0000]	-- General statement of exclusions or states
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"Sam Heard">
		["organisation"] = <"Ocean Informatics">
		["date"] = <"23/04/2006">
		["email"] = <"sam.heard@oceaninformatics.biz">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"For recording issues and health problems that are excluded from being relevant now or in the past.">
			use = <"This is for recording negative statements about issues in the record.">
			keywords = <"no", "significant", "family", "history", "surgery", "hospitalisations", "relevant", "allergies", "negation">
			misuse = <"">
		>
	>
	lifecycle_state = <"Initial">
	other_contributors = <>

definition
	EVALUATION[at0000] matches {	-- General statement of exclusions or states
		data matches {
			ITEM_TREE[at0001] matches {	-- Tree
				items cardinality matches {0..*; unordered} matches {
					ELEMENT[at0002] occurrences matches {1..*} matches {	-- Statement
						value matches {
							DV_CODED_TEXT matches {
								defining_code matches {
									[local::
									at0003, 	-- No significant illness
									at0004, 	-- No significant past history
									at0005, 	-- No significant family history
									at0006, 	-- No known adverse reactions
									at0004.1, 	-- No relevant past history
									at0005.1, 	-- No relevant family history
									at0006.1, 	-- No known allergies
									at0004.2, 	-- No hospitalisations
									at0004.3, 	-- No major surgery
									at0007, 	-- No known sensitivities
									at0008]	-- No known intolerances
								}
							}
						}
					}
				}
			}
		}
	}

ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					description = <"A category of conditions or states which have been excluded">
					text = <"General statement of exclusions or states">
				>
				["at0001"] = <
					description = <"@ internal @">
					text = <"Tree">
				>
				["at0002"] = <
					description = <"The statement about what is excluded">
					text = <"Statement">
				>
				["at0003"] = <
					description = <"The person has no significant medical condition">
					text = <"No significant illness">
				>
				["at0004"] = <
					description = <"The person has no significant past medical history">
					text = <"No significant past history">
				>
				["at0004.1"] = <
					description = <"No past problems or procedures relevant to the current situation">
					text = <"No relevant past history">
				>
				["at0004.2"] = <
					description = <"No admissions to hospital">
					text = <"No hospitalisations">
				>
				["at0004.3"] = <
					description = <"No major operations or procedures">
					text = <"No major surgery">
				>
				["at0005"] = <
					description = <"The person has no relatives with significant health problems">
					text = <"No significant family history">
				>
				["at0005.1"] = <
					description = <"No family history relevant to the current situation">
					text = <"No relevant family history">
				>
				["at0006"] = <
					description = <"The person has had no adverse reactions, including intolerances, sensitivities or allergies, to medications, food, animals or chemicals">
					text = <"No known adverse reactions">
				>
				["at0006.1"] = <
					description = <"No allergies known to any medications, foods or substances">
					text = <"No known allergies">
				>
				["at0007"] = <
					description = <"No sensitivity to any medications, foods or substances">
					text = <"No known sensitivities">
				>
				["at0008"] = <
					description = <"No known or recorded intolerances to medications, foods or other substances">
					text = <"No known intolerances">
				>
			>
		>
	>