archetype
	openEHR-EHR-OBSERVATION.height.v1draft

concept
	[at0000]	-- Length of the body

description
	original_author = <
		["name"] = <"Sam Heard">
		["organisation"] = <"Ocean Informatics">
		["date"] = <"2004-05-18">
	>
	lifecycle_state = <"draft">
	details = <
		["en"] = <
			language = <"en">
			purpose = <"Record height">
			misuse = <"infant">
			keywords = <"height", "adult">
			copyright = <"copyright (c) 2004 Ocean Informatics">
		>
	>


definition
	OBSERVATION[at0000] matches {	-- Length of the body
		data matches {
			HISTORY[at0001] matches {	-- history
				events cardinality matches {1..*; ordered} matches {
					EVENT[at0002] occurrences matches {0..*} matches {	-- Any event
						data matches {
							Single[at0003] matches {	-- Simple
								item matches {
									ELEMENT[at0004] matches {	-- Height
										name matches {
											CODED_TEXT matches {
												code matches {
													[local::
													at0005, 	-- Height
													at0006]	-- Length
												}
											}
										}
										value matches {
											C_QUANTITY <
												property = <"Length">
												list = <
													["1"] = <
														units = <"cm">
														magnitude = <|0.0..1000.0|>
													>
												>
											>
										}
									}
								}
							}
						}
					}
				}
			}
		}
		protocol matches {
			List[at0007] matches {	-- List
				items cardinality matches {0..1; ordered} matches {
					ELEMENT[at0008] occurrences matches {0..1} matches {	-- Device
						value matches {
							TEXT matches {*}
						}
					}
				}
			}
		}
	}

ontology
	primary_language = <"en">
	languages_available = <"en", ...>
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					description = <"Length of the body, in an extended position, from crown of head to sole of foot">
					text = <"Length of the body">
				>
				["at0001"] = <
					description = <"@ internal @">
					text = <"history">
				>
				["at0002"] = <
					description = <"*">
					text = <"Any event">
				>
				["at0003"] = <
					description = <"@ internal @">
					text = <"Simple">
				>
				["at0004"] = <
					description = <"The length of the body">
					text = <"Height">
				>
				["at0005"] = <
					description = <"Length of body in standing position">
					text = <"Height">
				>
				["at0006"] = <
					description = <"The length of the body supine">
					text = <"Length">
				>
				["at0007"] = <
					description = <"@ internal @">
					text = <"List">
				>
				["at0008"] = <
					description = <"The device used to measure the height">
					text = <"Device">
				>
			>
		>
	>